home *** CD-ROM | disk | FTP | other *** search
/ Aminet 1 (Walnut Creek) / Aminet - June 1993 [Walnut Creek].iso / usenet / sources / volume90 / util / gdostool / part01 / gdostool.s < prev    next >
Text File  |  1990-10-14  |  4KB  |  152 lines
  1. ; program to allow user examination and setting of ($0)
  2. ; 
  3. ; allows both simulation of the $0='GDOS' phenomena on some a590s and
  4. ; 2091s ( useful for testing code for nil pointer de-references and
  5. ; incorrect use of $0 when it should be #$0
  6. ;
  7. ; also allows clearing of $0, either to remove settings from previous
  8. ; use, or due to the a590/2091 itself
  9.  
  10. forbid        equ    -$084    ; offsets for various exec and int calls
  11. getmsg        equ    -$174    ; saves long includes and compile times
  12. replymsg    equ    -$17a
  13. waitport    equ    -$180
  14. findtask    equ    -$126
  15. autoreq        equ    -$15c
  16. openlib        equ    -$228
  17. closelib    equ    -$19e
  18.  
  19. pr_cli        equ    $0Ac    ; process cli flag offset
  20. pr_msgport    equ    $05c    ; process msgport offset
  21.  
  22. startup:    move.l    $4,a6
  23.         move.l    #0,a1
  24.         jsr    findtask(a6)        ; find ourselves
  25.  
  26.         move.l    d0,a4            ; save our process pointer
  27.  
  28.         move.l    pr_cli(a4),d0
  29.         bne    fromdos            ; was a DOS startup
  30.  
  31.         ; was started from WB
  32.  
  33.         lea    pr_msgport(a4),a0
  34.         jsr    waitport(a6)        ; wait for startup msg
  35.         lea    pr_msgport(a4),a0
  36.         jsr    getmsg(a6)        ; get the wb msg
  37.  
  38.         move.l    d0,wbmsg        ; save pointer to our startup msg
  39.         move.l    #1,wb            ; flag we started from wb
  40.  
  41. fromdos:    move.l    $0,d0
  42.         cmp.l    #$0,d0
  43.         beq    is_zero            ; if $0=0 then req already setup
  44.  
  45.         lea    nzbodytext,a0
  46.         move.l    a0,ctext        ; set so req displays non-zero msg
  47.         bra    _xx
  48.  
  49. is_zero:    lea    zbodytext,a0
  50.         move.l    a0,ctext
  51.  
  52. _xx:        lea    intuiname,a1
  53.         move.l    #0,d0
  54.         move.l    $4,a6
  55.         jsr    openlib(a6)         ; open intuition lib
  56.  
  57.         move.l    d0,a6            ; save ibase
  58.         
  59.         move.l    #0,a0            ; window to display in
  60.         move.l    #bodyitext,a1        ; body text
  61.         move.l    #yesitext,a2         ; postive text
  62.         move.l    #noitext,a3          ; negative text
  63.         move.l    #0,d0            ; pflags
  64.         move.l    #0,d1            ; nflags
  65.         move.l    #640,d2            ; width
  66.         move.l    #50,d3            ; height
  67.         jsr    autoreq(a6)        ; request user confirmation
  68.  
  69.         cmp.l    #0,d0
  70.         beq    cleargdos        ; user selected clear
  71.  
  72. setgdos:    move.l    #"GDOS",$0        ; set $0="GDOS"        
  73.         bra    _n1
  74.  
  75. cleargdos:    move.l    #$0,$0
  76.  
  77. _n1:        move.l    a6,a1            ; close intuition lib
  78.         move.l    $4,a6
  79.         jsr    closelib(A6)
  80.         
  81. exit:        move.l    wb,d0
  82.         cmp.l    #$0,d0            ; was this a CLI invocation
  83.         beq    exit_dos
  84.  
  85.         ; workbench exit
  86.  
  87.         move.l    $4,a6
  88.         jsr    forbid(a6)        ; lock out everyone else
  89.  
  90.         move.l    wbmsg,a1
  91.         jsr    replymsg(a6)        ; reply to Wbstartup msg
  92.  
  93. exit_dos:    move.l    #0,d0            ; return with return code 0
  94.         rts            
  95.  
  96. ;=============================================================
  97.         
  98. wb:        dc.l    0            ; run mode flag 0=dos process 1=wbprocess
  99. wbmsg:        dc.l    0            ; where we save our workbench msg
  100.  
  101. intuiname:    dc.b    "intuition.library",0
  102.  
  103. ; stuff for our autorequester
  104.  
  105. bodyitext:    dc.b    0           ; front pen
  106.         dc.b    1           ; back pen
  107.         dc.b    0           ; draw mode
  108.         dc.w    0           ; leftedge
  109.         dc.w    6           ; topedge
  110.         dc.l    0           ; textattr = default
  111.         dc.l    bodytext1      ; actual text
  112.         dc.l    nbodyitext     ; next
  113.  
  114. nbodyitext:    dc.b    0           ; front pen
  115.         dc.b    1           ; back pen
  116.         dc.b    0           ; draw mode
  117.         dc.w    0           ; leftedge
  118.         dc.w    20           ; topedge
  119.         dc.l    0           ; textattr = default
  120. ctext:        dc.l    0          ; actual text
  121.         dc.l    0         ; next
  122.  
  123.  
  124. yesitext:    dc.b    2        ; front pen
  125.         dc.b    1        ; back pen
  126.         dc.b    0        ; draw mode
  127.         dc.w    4        ; leftedge
  128.         dc.w    4        ; topedge
  129.         dc.l    0        ; textattr = default
  130.         dc.l    yestext        ; actual text
  131.         dc.l    0        ; next
  132.         
  133. noitext:    dc.b    2        ; front pen
  134.         dc.b    1        ; back pen
  135.         dc.b    0        ; draw mode
  136.         dc.w    4        ; leftedge
  137.         dc.w    4        ; topedge
  138.         dc.l    0        ; textattr = default
  139.         dc.l    notext        ; actual text
  140.         dc.l    0        ; next        
  141.  
  142.         ; actual text for our requester
  143.  
  144. bodytext1:    dc.b    "   SetGDOS by J Davis, 08-1990 v1.0 - an aid to hunting nil pointer de-refs",0
  145. zbodytext:    dc.b    "                  Location $0 currently holds a NULL (0) value",0
  146. nzbodytext:    dc.b    "                     Location $0 is currently NON-ZERO",0
  147.  
  148. yestext:    dc.b    "Set $0='GDOS'",0
  149. notext:        dc.b    "Set $0=NULL",0
  150.  
  151.         END
  152.